' the object's DoneOnThisScanline flag appropriately.
Public Sub RayTraceable_CullScanline(ByVal px As Single, ByVal py As Single, ByVal pz As Single, ByVal Nx As Single, ByVal Ny As Single, ByVal Nz As Single)
' See if we will ever be visible again.
If ForeverCulled Then
DoneOnThisScanline = True
Exit Sub
End If
' We have not yet had a hit on this scanline.
HadHit = False
' Do not scanline cull.
DoneOnThisScanline = False
End Sub
' Return the value T for the point of intersection
' between the vector from point (px, py, pz) in
' the direction <wx, wy, wz>.
'
' direct_calculation is true if we are finding the
' intersection from a viewing position ray. It is
' false if we are finding an reflected intersection
' or a shadow feeler.
Public Function RayTraceable_FindT(ByVal direct_calculation As Boolean, ByVal px As Single, ByVal py As Single, ByVal pz As Single, ByVal Vx As Single, ByVal Vy As Single, ByVal Vz As Single) As Single
Dim x1 As Single
Dim y1 As Single
Dim z1 As Single
Dim Wx As Single
Dim Wy As Single
Dim Wz As Single
Dim w_len_squared As Single
Dim WdotV As Single
Dim A As Single
Dim B As Single
Dim Cx As Single
Dim Cy As Single
Dim Cz As Single
Dim dx As Single
Dim dy As Single
Dim dz As Single
Dim A1 As Single
Dim b1 As Single
Dim C1 As Single
Dim B24AC As Single
Dim t1 As Single
Dim t2 As Single
' Find the axis vector.
Wx = Point2.Trans(1) - Point1.Trans(1)
Wy = Point2.Trans(2) - Point1.Trans(2)
Wz = Point2.Trans(3) - Point1.Trans(3)
' Find A and B for u = A * t + B.
w_len_squared = Wx * Wx + Wy * Wy + Wz * Wz
WdotV = Wx * Vx + Wy * Vy + Wz * Vz
A = WdotV / w_len_squared
x1 = Point1.Trans(1)
y1 = Point1.Trans(2)
z1 = Point1.Trans(3)
B = (Wx * (px - x1) + _
Wy * (py - y1) + _
Wz * (pz - z1)) / w_len_squared
' Solve for t.
Cx = Vx - Wx * A
Cy = Vy - Wy * A
Cz = Vz - Wz * A
dx = px - x1 - Wx * B
dy = py - y1 - Wy * B
dz = pz - z1 - Wz * B
A1 = Cx * Cx + Cy * Cy + Cz * Cz
b1 = 2 * (Cx * dx + Cy * dy + Cz * dz)
C1 = dx * dx + dy * dy + dz * dz - Radius * Radius
' Solve the quadratic A1*t^2 + B1*t + C1 = 0.
B24AC = b1 * b1 - 4 * A1 * C1
If B24AC < 0 Then
RayTraceable_FindT = -1
Exit Function
ElseIf B24AC = 0 Then
t1 = -b1 / 2 / A1
Else
B24AC = Sqr(B24AC)
t1 = (-b1 + B24AC) / 2 / A1
t2 = (-b1 - B24AC) / 2 / A1
' Use only positive t values.
If t1 < 0.02 Then t1 = t2
If t2 < 0.02 Then t2 = t1
' Use the smaller t value.
If t1 > t2 Then t1 = t2
End If
' If there is no positive t value, there's no
' intersection in this direction.
If t1 < 0.02 Then
RayTraceable_FindT = -1
Exit Function
End If
' See where on the cylinder this point is.
HitU = t1 * A + B
' If this is not between Point1 and Point2,
' ignore it.
If HitU < 0 Or HitU > 1 Then
RayTraceable_FindT = -1
Else
RayTraceable_FindT = t1
End If
End Function
' Return the minimum and maximum distances from
' this point.
Private Sub RayTraceable_GetRminRmax(new_min As Single, new_max As Single, ByVal X As Single, ByVal Y As Single, ByVal Z As Single)
Dim dx As Single
Dim dy As Single
Dim dz As Single
Dim dist As Single
' Find the distance to the first point.
dx = X - Point1.Trans(1)
dy = Y - Point1.Trans(2)
dz = Z - Point1.Trans(3)
dist = Sqr(dx * dx + dy * dy + dz * dz)
new_max = dist + Radius
new_min = dist - Radius
' Find the distance to the second point.
dx = X - Point2.Trans(1)
dy = Y - Point2.Trans(2)
dz = Z - Point2.Trans(3)
dist = Sqr(dx * dx + dy * dy + dz * dz)
If new_max < dist + Radius Then new_max = dist + Radius
If new_min > dist - Radius Then new_min = dist - Radius
